When I add a word to a dictionary in Microsoft Word, will it be marked as error ...

I have a document in which I want to add a new word to a dictionary. To can add a new word to a dictionary, I have to create custom dictionary first, because if not, the add word is disabled.

Well, my doubt is, if I share this document to another person, the word that I added to the dictionary to don't be marked as incorrect, will it be marked as incorrect when the other person will open the document?

If this is true, there is some way to embedded a dictionary to the document or mark this work as correct and it will not be marked as incorrect to other people that open this document?

Thanks.

Yes, a word in your custom dictionary will still show up as an error on the other computer. Instead, you can mark the word to not check spelling (on any computer).

Adding a word to your custom dictionary tells Word to approve that spelling on your computer when it runs a spell check. It has no effect when someone else opens it on a different computer, though.

Words and phrases in Word can be marked so that they are skipped in spelling checks and do not show up as errors in Word on any computer. This can be done by applying that setting to the text through the proofing language dialog or by using a character style with the setting. Such marking works on all computers opening the document in Word regardless of whether or not the word is in a user's dictionary of acceptable spellings. This is a form of invisible character formatting, not unlike Bold or Italics. See Word MVP Suzanne Barnhill's page on Mastering the Spelling Checker.

Here is my article on creating a character style that you can use to mark words/phrases to not have spelling checked. Here are two of the macros from that article:

Sub NoSpellCheckStyle()  ' SEE ALSO ASSIGNSHORTCUTNOSPELLCHECK FOLLOWING
    ' Charles Kenyon
    ' Creates a character style named "No Spell Check" in the Active Document
    ' Does NOT apply the style to a selection, simply creates the style
    ' 12 April 2019
    '
    Dim stlNoCheck As Style
    '
    On Error GoTo ErrorAlreadyExists
    Set stlNoCheck = ActiveDocument.Styles.Add(Name:="No Spell Check", Type:=wdStyleTypeCharacter)
    On Error GoTo -1
    With stlNoCheck
        .Font.Name = ""
        .NoProofing = True
    End With
    GoTo ExitSub
ErrorAlreadyExists:
    MsgBox Prompt:="Style 'No Spell Check' already exists", Buttons:=vbInformation, title:="Oops"
ExitSub:
    Set stlNoCheck = Nothing
End Sub

Sub AssignShortcutNoSpellCheck()
'
' Charles Kenyon ---- GOES WITH PREVIOUS MACRO
' 2 March 2021
' Assigns keyboard shortcut Ctrl+Shift+Alt+N to No Spell Check style
'   Style must exist
'   Saves this in the active document
'
    CustomizationContext = ActiveDocument ' Change ActiveDocument to NormalTemplate if style is in Normal Template
    KeyBindings.Add KeyCode:=BuildKeyCode(wdKeyN, wdKeyControl, _
        wdKeyShift, wdKeyAlt), _
        KeyCategory:=wdKeyCategoryStyle, _
        Command:="No Spell Check"
End Sub

My article also has a macro for a paragraph style and links to directions on how to use macros.